ASP 接收不同编码提交的参数

utf-8页面，接收gbk参数， 或者 gbk 页面接收 utf-8 参数，或者...
很少会出现这样的参求，但有时候却是不得己

比如说合作网站提交过来的数据。。。

e， 不瞎扯，直接代码

1. <script language="jscript" runat="Server">
   
2. function decodeURL(str, cSet) {
   
3.         with (Server.CreateObject("ADODB.Stream")) {
   
4.                 Type=2; Charset="iso-8859-1"; Open(); WriteText(unescape(str.replace(/\+/g, "%20")));
   
5.                 Position=0; Charset=cSet; str=ReadText(-1); Close();
   
6.         }
   
7.         return str;
   
8. }
   
9. function getParameter(paramName, encodingForDecode, dictionary) {
   
10.         var values = [];
    
11.         dictionary.Item.replace(new RegExp("(?:^|&)" + paramName + "=([^&]*)", "gi"), function($, $1) {
    
12.                 values.push(decodeURL($1, encodingForDecode));
    
13.         });
    
14.         return values;
    
15. }
    
16. </script>
    
17. <%=getParameter("gbkParam", "GBK", Request.QueryString)%><br />
    
18. <%=getParameter("utfParam", "UTF-8", Request.QueryString)%><br />

复制代码

VBScript 实现
测试地址：http://localhost/1.asp?gbkParam=%D6%D0%CE%C4%B0%A1&utfParam=%E4%B8%AD%E6%96%87%E5%95%8A

1. <%
   
2. Class StringList
   
3.     Private dict, strName, i
   
4. 
   
5.     Private Sub Class_Initialize()
   
6.         Set dict = CreateObject("Scripting.Dictionary")
   
7.         i = 0
   
8.     End Sub
   
9.    
   
10.     Public Property Get Count()
    
11.         Count = i
    
12.     End Property
    
13.    
    
14.     Public Property Let Name(newValue)
    
15.         strName = newValue
    
16.     End Property
    
17.    
    
18.     Public Property Get Name()
    
19.         Name = strName
    
20.     End Property
    
21.    
    
22.     Public Sub Add(strValue)
    
23.         i = i + 1
    
24.         dict.Add i, strValue
    
25.     End Sub
    
26.    
    
27.     Public Default Property Get ToString()
    
28.         ToString = Me.Item(Empty)
    
29.     End Property
    
30.    
    
31.     Public Property Get Item(index)
    
32.         If Not IsEmpty(index) And IsNumeric(index) Then
    
33.             If index<1 Then Err.Raise -1, "StringList.Item", "下标越界"
    
34.             If index>i Then Err.Raise -1, "StringList.Item", "下标越界"
    
35.             Item = dict.Item(index)
    
36.         ElseIf i>0 Then
    
37.             Item = Join(dict.Items(), ", ")
    
38.         End If
    
39.     End Property
    
40. End Class
    
41. 
    
42. Function decodeURIComponent(str, cSet)
    
43.     With Server.CreateObject("ADODB.Stream")
    
44.         .Type = 2
    
45.         .Charset = "iso-8859-1"
    
46.         .Open
    
47.         .WriteText UnEscape(Replace(str, "+", "%20"))
    
48.         .Position = 0
    
49.         .Charset = cSet
    
50.         decodeURIComponent = .ReadText(-1)
    
51.         .Close
    
52.     End With
    
53. End Function
    
54. 
    
55. Function getParameter(name, cSet, dictionary)
    
56.     Dim match : Set getParameter = New StringList : getParameter.Name = name
    
57.     With New RegExp
    
58.         .Pattern = "(?:^|&)" & Server.URLEncode(name) & "=([^&]*)"
    
59.         .Global = True
    
60.         For Each match In .Execute(dictionary)
    
61.             getParameter.Add decodeURIComponent(match.Submatches.Item(0), cSet)
    
62.         Next
    
63.     End with
    
64. End Function
    
65. 
    
66. 
    
67. %>
    
68. <%=getParameter("gbkParam", "GBK", Request.QueryString)%><br />
    
69. <%=getParameter("utfParam", "UTF-8", Request.QueryString)%><br />
    
70. <%=getParameter("utfParam", "UTF-8", Request.QueryString).Count%><br />
    
71. <%=getParameter("utfParam", "UTF-8", Request.QueryString).Item(1)%><br />

复制代码

坛主，这个好像用不了啊。
我utf-8页面，接收gb2312编码参数，还是不行。

回复 2# exitdos

具体什么情况QQ啊
78423497